Updated to libreforge 4

2023-03-27 19:04:09 +01:00
parent 98690e936b
commit 107efb5f92
25 changed files with 362 additions and 464 deletions
@@ -0,0 +1,81 @@
+plugins {
+    java
+    `java-library`
+    `maven-publish`
+    kotlin("jvm") version "1.7.10"
+    id("com.github.johnrengelman.shadow") version "8.0.0"
+    id("com.willfp.libreforge.gradle") version "1.0.0"
+}
+
+group = "com.willfp"
+version = findProperty("version")!!
+val libreforgeVersion = findProperty("libreforge-version")
+
+base {
+    archivesName.set(project.name)
+}
+
+dependencies {
+    project(":eco-core").dependencyProject.subprojects {
+        implementation(this)
+    }
+}
+
+allprojects {
+    apply(plugin = "java")
+    apply(plugin = "kotlin")
+    apply(plugin = "maven-publish")
+    apply(plugin = "com.github.johnrengelman.shadow")
+
+    repositories {
+        mavenLocal()
+        mavenCentral()
+
+        maven("https://repo.papermc.io/repository/maven-public/")
+        maven("https://jitpack.io")
+    }
+
+    dependencies {
+        compileOnly("com.willfp:eco:6.53.0")
+        compileOnly("org.jetbrains:annotations:23.0.0")
+        compileOnly("org.jetbrains.kotlin:kotlin-stdlib:1.7.10")
+    }
+
+    java {
+        withSourcesJar()
+        toolchain.languageVersion.set(JavaLanguageVersion.of(17))
+    }
+
+    tasks {
+        shadowJar {
+            relocate("com.willfp.libreforge.loader", "com.willfp.boosters.libreforge.loader")
+        }
+
+        compileKotlin {
+            kotlinOptions {
+                jvmTarget = "17"
+            }
+        }
+
+        compileJava {
+            options.isDeprecation = true
+            options.encoding = "UTF-8"
+
+            dependsOn(clean)
+        }
+
+        processResources {
+            filesMatching(listOf("**plugin.yml", "**eco.yml")) {
+                expand(
+                    "version" to project.version,
+                    "libreforgeVersion" to libreforgeVersion,
+                    "pluginName" to rootProject.name
+                )
+            }
+        }
+
+        build {
+            dependsOn(shadowJar)
+        }
+    }
+}