plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '6.1.0'
    id "io.freefair.lombok" version "5.1.0"
}

group 'sh.okx'
version '3.12.1'

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

repositories {
    mavenCentral()
    maven {
        url 'https://hub.spigotmc.org/nexus/content/groups/public/'
    }
    maven {
        url 'https://repo.extendedclip.com/content/repositories/placeholderapi/'
    }
    maven {
        url 'https://raw.github.com/PyvesB/AdvancedAchievements/mvn-repo/'
    }
    maven {
        url 'https://jitpack.io'
    }
}

dependencies {
    testImplementation group: 'junit', name: 'junit', version: '4.12'
    testImplementation 'com.github.seeseemelk:MockBukkit-v1.16:1.0.0'
    testImplementation group: 'org.slf4j', name: 'slf4j-nop', version: '1.7.30'
    testImplementation group: 'org.slf4j', name: 'slf4j-api', version: '1.7.30'

    compileOnly 'org.jetbrains:annotations:16.0.2'
    compileOnly 'org.spigotmc:spigot-api:1.17-R0.1-SNAPSHOT'
    compileOnly('com.github.Realizedd:TokenManager:3.2.4') {
        transitive = false
    }

    compileOnly('com.github.MilkBowl:VaultAPI:1.7') {
        exclude group: 'org.bukkit'
    }
    compileOnly ('me.clip:placeholderapi:2.10.9') {
        exclude group: 'org.bstats'
    }
    compileOnly 'com.github.pyvesb:advanced-achievements:6.7.2'
    compileOnly 'com.github.astei:Superbvote:700fca43659b438cb9bb36c218a7646d2f2ef315'
    compileOnly('com.github.mcMMO-Dev:mcMMO:601297') {
        exclude group: 'com.sk89q.worldguard'
    }
    compileOnly 'com.github.BenCodez:VotingPlugin:6.0'
    compileOnly 'com.github.LlmDl:Towny:25fc18a'

    implementation ('io.pebbletemplates:pebble:3.1.5') {
        exclude group: 'org.slf4j'
    }
}

artifacts {
    archives shadowJar
}

shadowJar {
    archiveClassifier.set('')
    minimize()
}

// automatically copy the version to plugin.yml
processResources {
    // do this again whenever version changes
    inputs.property 'version', project.version

    // copy plugin.yml and replace version
    from(sourceSets.main.resources.srcDirs) {
        include 'plugin.yml'
        expand 'version': project.version
    }

    // copy everything else
    from(sourceSets.main.resources.srcDirs) {
        exclude 'plugin.yml'
    }
}

task spigot(type: com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar) {
    from sourceSets.main.runtimeClasspath
    destinationDirectory = file("./spigot/plugins/")
    archiveFileName = "Rankup.jar"
}